Delphi Magazine Collection 2001/Delphi Magazine Collection 20001 (2001).iso/DISKS/Issue43/tooltips/HintGrid.pas

Pascal/Delphi Source File | 1999-01-25 | 4.8 KB | 180 lines

unit HintGrid;
{$ifdef Ver80} { Delphi 1.0x }
  {$define DelphiLessThan3}
{$endif}
{$ifdef Ver90} { Delphi 2.0x }
  {$define DelphiLessThan3}
{$endif}
{$ifdef Ver93} { C++ Builder 1.0x }
  {$define DelphiLessThan3}
{$endif}

interface

uses
  WinProcs, WinTypes, Messages, SysUtils, Classes, Graphics, Controls, Forms,
  Dialogs, Grids;

type
  THintStringGrid = class(TStringGrid)
  private
    FHintWnd: THintWindow;
  protected
    function CalcHintRect(MaxWidth: Integer;
      const AHint: string; HintWnd: THintWindow): TRect;
    procedure DoHint(X, Y: Integer);
  public
    procedure CMMouseEnter(var Msg: TMessage); message cm_MouseEnter;
    procedure CMMouseLeave(var Msg: TMessage); message cm_MouseLeave;
    procedure WMMouseMove(var Msg: TWMMouseMove); message wm_MouseMove;
  end;

{$ifdef DelphiLessThan3}
  { The hint window in Delphi 1 and 2 would beep if you clicked it }
  { These modifications fix that }
  TCustomHint = class(THintWindow)
  private
    procedure WMNCHitTest(var Msg: TWMNCHitTest);
      message wm_NCHitTest;
  protected
    procedure CreateParams(var Params: TCreateParams); override;
  end;

{ The private routine Forms.ForegroundTask was only made }
{ available in Delphi 3. This is a cheap'n'nasty version of it }
function ForegroundTask: Boolean;
{$endif}

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Clinic', [THintStringGrid]);
end;

{$ifdef DelphiLessThan3}
{ The private routine Forms.ForegroundTask was only made }
{ available in Delphi 3. This is a cheap'n'nasty version of it }
function ForegroundTask: Boolean;
begin
  Result := FindControl(GetActiveWindow) <> nil
end;
{$endif}

{ THintStringGrid }

function THintStringGrid.CalcHintRect(MaxWidth: Integer;
  const AHint: string; HintWnd: THintWindow): TRect;
{$ifdef DelphiLessThan3}
var
  Buf: array[0..511] of Char;
begin
  Result := Rect(0, 0, MaxWidth, 0);
  { Ask Windows to do the hard calculation work }
  DrawText(HintWnd.Canvas.Handle, StrPCopy(Buf, AHint), -1, Result,
    DT_CALCRECT or DT_LEFT or DT_WORDBREAK or DT_NOPREFIX);
  { Add some breathing room }
  Inc(Result.Right, 6);
  Inc(Result.Bottom, 2);
{$else}
begin
  { Delphi 3+ makes this method available }
  Result := HintWnd.CalcHintRect(Screen.Width, AHint, nil)
{$endif}
end;

procedure THintStringGrid.CMMouseEnter(var Msg: TMessage);
var
  Pt: TPoint;
begin
  GetCursorPos(Pt);
  Pt := ScreenToClient(Pt);
  DoHint(Pt.X, Pt.Y)
end;

procedure THintStringGrid.CMMouseLeave(var Msg: TMessage);
begin
  inherited;
  { Could destroy it, but this takes less time }
  if Assigned(FHintWnd) then
    FHintWnd.ReleaseHandle;
end;

procedure THintStringGrid.DoHint(X, Y: Integer);
const
  TextOffset = 2;
var
  Col, Row: Longint;
  R, OldR: TRect;
  Pt: TPoint;
begin
  { Check cell under mouse }
  MouseToCell(X, Y, Col, Row);
  { If it is a cell, and text is bigger than screen space, }
  { and in-place editor not present, and not at design-time }
  Canvas.Font := Font;
  if (Col <> -1) and (Row <> -1) and
     (Canvas.TextWidth(Cells[Col, Row]) + TextOffset > ColWidths[Col]) and
     not EditorMode and ForegroundTask and not (csDesigning in ComponentState) then
  begin
    { Make sure hint window exists }
    if not Assigned(FHintWnd) then
    begin
      FHintWnd := HintWindowClass.Create(Self);
      FHintWnd.Color := Application.HintColor;
    end;
    { Set hint text }
    Hint := Cells[Col, Row];
    { Calculate rect size }
    R := CalcHintRect(Screen.Width, Hint, FHintWnd);
    { Find target location }
    Pt := ClientToScreen(CellRect(Col, Row).TopLeft);
    { Tweak position so it is the same as the grid cell (hopefully) }
  {$ifdef DelphiLessThan3}
    Inc(Pt.Y);
  {$else}
    Dec(Pt.X);
    Dec(Pt.Y);
  {$endif}
    OffsetRect(R, Pt.X, Pt.Y);
    { Only draw it if it has moved - compare top-left }
    { (could compare whole rect but the hint sometimes grows itself) }
    GetWindowRect(FHintWnd.Handle, OldR);
    if not IsWindowVisible(FHintWnd.Handle) or
       not ((R.Left = OldR.Left) and (R.Top = OldR.Top)) then
      FHintWnd.ActivateHint(R, Hint)
  end
  else
    if Assigned(FHintWnd) then
      FHintWnd.ReleaseHandle;
end;

procedure THintStringGrid.WMMouseMove(var Msg: TWMMouseMove);
begin
  inherited;
  DoHint(Msg.XPos, Msg.YPos)
end;

{$ifdef DelphiLessThan3}
{ TCustomHint }

procedure TCustomHint.CreateParams(var Params: TCreateParams);
begin
  inherited CreateParams(Params);
  Params.Style := Params.Style and not ws_Disabled;
end;

procedure TCustomHint.WMNCHitTest(var Msg: TWMNCHitTest);
begin
  Msg.Result := HTTRANSPARENT;
end;

initialization
  Application.ShowHint := not Application.ShowHint;
  HintWindowClass := TCustomHint;
  Application.ShowHint := not Application.ShowHint;
{$endif}
end.